I built this robot over many variations, most of which are shown in various forms on this very website.

Well Now, I`ve gone and Made My Robot Into an Autonomous Pickup Truck... It`s working well enough to smash into things, but avoid smashing into me.

I will fearlessly step in front of a power-chair controlled by a couple of chips with IR sensors. This sounds like a movie promo: "See video of human interacting with primitive robots."

Barefoot. On the deck. This project shows you how often the robot actually has me walking around the deck with it. Disregard the Deck Furniture variously stacked around the place, I want the thing to see and navigate them, but not just yet.

Did I mention this thing is held together by gravity and rubber bands? I said the robot was primitive, I just didn`t mention the human was also primitive.

The PVC Frame sits on top of the cover of the mini Jazzy. It is held in place only by the large areas of contact the PVC makes with the body. Since there is significant weight, the frame sits quite still, even in sometimes violent interactions with items the Robot fails to navigate.

The PVC Frame sits on top of the cover of the mini Jazzy. It is held in place only by the large areas of contact the PVC makes with the body. Since there is significant weight, the frame sits quite still, even in sometimes violent interactions with items the Robot fails to navigate.

This results in a flat-bed for the bot, one which was designed to hold two grocery bags side by side.

I haven`t trusted this thing yet to haul actual groceries, nor has it left the confines of the back deck.

But, just watch me talking to it, following it around like a human pet. And you will know, soon it will be asking for the car keys!!!

The large and in-charge pieces are wrapped in rubber bands.

The rubber bands are sometimes wrapped around the pvc pipes as well when more strength is needed.

The whole electronics package including RGB LED that can flash colors to tell us when the Robot sees an object in it`s field.

There are many projects on this site which deal with each stage of development.

Sizing the resistors for proper forward/reverse and left/right speeds. (Be very careful with speed, we are asking sensors to determine inches a couple inches moving can crush bone or produce painful bruises.)

Locating the connections to the correct pins in the controller. Bringing the wires out ( +,-,F/R,L/R )

Using the picAxe (or Arduino) Controller to control a set of LEDs to use as indicators, and to control the dual H-Bridge so it provides 3-State signals to the Joystick in the controller.

The H-Bridge is driven by controlling the length of the "on" time while allowing you to switch between: GND, +Vcc, and Open. By using a dual H-Bridge, you can move forward and steer right or left with another timed tri-state signal.

In this prototype version, I mounted the whole thing on a proto-jumper board so I could sort of organically grow the sensors, and indicators. I already plan to use ultrasonic transducers, now that I have IR controlling the base pretty safely. What comes after Ultrasonics?

Video is in there as well as some kind of integrated RF, but the base of the thing is most important, and will, on it`s own navigate a fairly cluttered environment.

This is the software that allows you to fine-tune your unit so it works best for your application.

-----------------------------------------------

`-----------------------------------------------------------------------------
; ***** Power Chair Robot *****
;
; Filename: pongTestBase04.bas
; Date: 10/01/2013
;
; File Version: 0.4
; Written by: Jim H
; Used to test FrameWork Bot,
; Permits you to find which of the sensors has detected what value
; Press Red Button to go until an obstruction, where you stop
; Operates with 3 sensors Left=Red, Center=Grn, Right = Blu RGBLED

` ------------------------------------------------------------
` Compiler Directives
#picaxe 20m2
` -----------------------------
`
` Pinout and Definition of Legs
`
`````````````````````````````````````````````````````
`
`pin 1 VCC ` pin 20 VSS
`pin 2 SerialIn pin 19 a.0 SerialOut
`pin 3 C.7 ADC3/Out/In pin 18 b.0 ADC1/In/Out
`pin 4 C.6 IN pin 17 b.1 ADC2/in/out
`pin 5 C.5 hpwmA/pwm/out/in pin 16 b.2 ADC4/in/out
`pin 6 C.4 hpwmB,SRNQ/out/in pin 15 b.3 ADC5/in/out
`pin 7 C.3 ADC7/hpwmC/out/in pin 14 b.4 ADC6/hpwmD/in/out
`pin 8 C.2 ADC8/kb clk/out/in pin 13 b.5 ADC10/hi2c sda/hspi sdi/in/out
`pin 9 C.1 ADC9/hspi sdo/kb data/out/in pin 12 b.6 ADC11/hserin/in/out
`pin 10 C.0 hserout/out/in pin 11 b.7 hi2c scl/hspi sck/in/out

` -------------------------------------------------------------
` Program Wide Symbols
Symbol rtFrontSensor = W0
Symbol frontSensor = W1
Symbol lftFrontSensor = w2
Symbol rearSensor = w3
Symbol sensorTemp = w4

Symbol flag = w5

Symbol frontRight = b.0 `pin 18
Symbol frontCenter = b.1 `pin 17
Symbol fwdRev = b.2 `pin 16
Symbol enFR = b.3 `pin 15
Symbol lftRgt = b.4 `pin 14
Symbol backCenter = b.5 `pin 13
Symbol enLR = b.6 `pin 12
Symbol scl = b.7 `pin 11

Symbol frontLeft = c.1 `pin 9
Symbol ledRed = c.2 `pin 8
Symbol ledBlu = c.3 `pin 7
Symbol ledGrn = c.4 `pin 6

Symbol click = c.6 `pin 4 the button
Symbol IRdet = c.7 `pin 3 adc3

Symbol frontLimit = 130
Symbol backLimit = 200

Symbol rgtLimit = 210
Symbol lftLimit = 220

Symbol irLimit = 400


` initialize ---------------------------------------------------
let dirsB = %11011100
let dirsC = %00011100

low enFR, enLR ` Shut Drive Motors
setfreq m8 ` NOTE: operates at 9600 baud (setfreq m8)

`---------------------------------------------------------------
` System Operation
`
` subs:
` look fwd
` look back
` check values and
` continue
` stop
` turnLeft `steer
` turnRight `steer
` backup
`
`----------------------------------------------------------------
`----------------------------------------------------------------
;;;goto repeater
let flag = 255
Pause 100 ` allow system to settle when booting
high ledGrn, ledBlu, ledRed `warning lights offcc z

loopDeloop:
if pinC.6 = 1 then
low enFR, enLR ` Shut Drive Motors
` gosub lookFwd ` get Value in rtFrontSensor
` gosub lookBak ` get Value in lftFrontSensor
` gosub displayIt
pause 20
goto loopDeloop
else
goto mainProg
endif



mainProg:
`goto repeater ; Uncomment this to run the repeater loop simple F/B/L/R, and again...
high ledGrn, ledBlu, ledRed `warning lights off

` ----- move forward, evaluate, proceed, unless backup
gosub lookFwd ` get Value in rtFrontSensor
gosub lookBak ` get Value in backUpSensor
` gosub displayIt ; Use for debugging only if you are stuck, too much delay

if lftFrontSensor >= lftLimit OR lftFrontSensor >= irLimit then ; reached the limit:stop:in this version
low enFR,enLR `stop
low ledRed
goto loopDeloop
endif

if frontSensor >= frontLimit OR frontSensor >= irLimit then
low enFR,enLR `stop
low ledGrn
goto loopDeloop
endif

if rtFrontSensor >= rgtLimit OR rtFrontSensor >= irLimit then
low enFR,enLR `stop
low ledBlu
goto loopDeloop
endif

; if rearSensor >= backLimit then
; low enFR,enLR `stop
; goto loopDeloop
; endif

; if rearSensor < backLimit then
; high enFR
; low fwdRev `go forward
; pause 50 `kick brakes off, etc
; endif

high enFR, fwdRev `go forward
low enLR ` I said Forward Fool!
pause 50 `kick brakes off, etc

goto mainProg
`



displayIt:
;------ stream values to serial port
`setfreq m4 `if you have only 4800 baud
SerTxD("F: ",#frontSensor," L: ",#lftFrontSensor," R: ", #rtFrontSensor," Back: ",#rearSensor,CR, LF,CR,LF)
pause 200 ; give the tty a breather..
return

lookFwd:
` RIGHT
;----- Look rtFrontSensor
let sensorTemp = rtFrontSensor ` last sample
readadc10 frontRight, rtFrontSensor ` sonar ana input
rtFrontSensor = rtFrontSensor + sensorTemp
rtFrontSensor = rtFrontSensor / 2
pause 10 `steady... steady...

` LEFT
;----- Look lftFrontSensor
let sensorTemp = lftFrontSensor ` last sample
readadc10 frontLeft,lftFrontSensor
pause 10 `let it settle
lftFrontSensor = lftFrontSensor + sensorTemp
lftFrontSensor = lftFrontSensor / 2

;----- CENTER FRONT
let sensorTemp = frontSensor ` last sample
readadc10 frontCenter,frontSensor
pause 10 `let it settle
frontSensor = frontSensor + sensorTemp
frontSensor = frontSensor / 2
return

lookBak:
;----- Look back Sensor
let sensorTemp = rearSensor ` last sample
readadc10 backCenter, rearSensor ` sonar ana input
pause 10 `steady... steady...
rearSensor = rearSensor + sensorTemp
rearSensor = rearSensor / 2
return

repeater:
; --- Repeater moves a short distance in each of the four directions:
; Forward, Reverse, Right then Left continuously

high enFR
high fwdRev `forward
pause 2500
low fwdRev,enFR `stop
pause 1600

high enFR
low fwdRev `reverse
pause 3100
low fwdRev,enFR `stop
pause 1600


high enLR `left
high lftRgt
pause 2500
low lftRgt,enLR `stop
pause 1600

high enLR
low lftRgt `right
pause 2500
low lftRgt,enLR
pause 1600
goto repeater

Don`t go without shoes when you run this (Although I did, in the video).

This is what one would call Operational Base Unit Code Release 0.1 meaning, it works, with no guarantees that I got anything right. If you do this correctly, you will change some values when you run the test code. Change to the tested values you came up with during testing runs (run and stop).


`-----------------------------------------------------------------------------
; ***** Power Chair Robot *****
;
; Filename: pongBase01.bas
; Date: 10/02/2013
;
; File Version: 0.1
; Written by: Jim H
; Built On Test FrameWork Bot,
; Permits you to find which of the sensors has detected what value
; Press Red Button to go until an obstruction, where you stop
; Operates with 3 sensors Left=Red, Center=Grn, Right = Blu RGBLED
;
; Red Turn Left
; Green Stop Backup Turn Random(Left/Right) recheck, then react
; Blue Turn Right

` ------------------------------------------------------------
` Compiler Directives
#picaxe 20m2
` -----------------------------
`
` Pinout and Definition of Legs
`
`````````````````````````````````````````````````````
`
`pin 1 VCC ` pin 20 VSS
`pin 2 SerialIn pin 19 a.0 SerialOut
`pin 3 C.7 ADC3/Out/In pin 18 b.0 ADC1/In/Out
`pin 4 C.6 IN pin 17 b.1 ADC2/in/out
`pin 5 C.5 hpwmA/pwm/out/in pin 16 b.2 ADC4/in/out
`pin 6 C.4 hpwmB,SRNQ/out/in pin 15 b.3 ADC5/in/out
`pin 7 C.3 ADC7/hpwmC/out/in pin 14 b.4 ADC6/hpwmD/in/out
`pin 8 C.2 ADC8/kb clk/out/in pin 13 b.5 ADC10/hi2c sda/hspi sdi/in/out
`pin 9 C.1 ADC9/hspi sdo/kb data/out/in pin 12 b.6 ADC11/hserin/in/out
`pin 10 C.0 hserout/out/in pin 11 b.7 hi2c scl/hspi sck/in/out

` -------------------------------------------------------------
` Program Wide Symbols
Symbol rtFrontSensor = W0
Symbol frontSensor = W1
Symbol lftFrontSensor = w2
Symbol rearSensor = w3
Symbol sensorTemp = w4
Symbol flag = w5

Symbol frontRight = b.0 `pin 18
Symbol frontCenter = b.1 `pin 17
Symbol fwdRev = b.2 `pin 16
Symbol enFR = b.3 `pin 15
Symbol lftRgt = b.4 `pin 14
Symbol backCenter = b.5 `pin 13
Symbol enLR = b.6 `pin 12
Symbol scl = b.7 `pin 11

Symbol frontLeft = c.1 `pin 9
Symbol ledRed = c.2 `pin 8
Symbol ledBlu = c.3 `pin 7
Symbol ledGrn = c.4 `pin 6

Symbol click = c.6 `pin 4 the button
Symbol IRdet = c.7 `pin 3 adc3

Symbol frontLimit = 100
Symbol backLimit = 350

Symbol rgtLimit = 150
Symbol lftLimit = 150

Symbol irLimit = 400


` initialize ---------------------------------------------------
let dirsB = %11011100
let dirsC = %00011100

low enFR, enLR ` Shut Drive Motors
setfreq m8 ` NOTE: operates at 9600 baud (setfreq m8)

let flag = 255
Pause 100 ` allow system to settle when booting
high ledGrn, ledBlu, ledRed `warning lights offcc z
`---------------------------------------------------------------
` System Operation
`
` subs:
` look fwd
` look back
` check values and
` continue
` stop
` turnLeft `steer
` turnRight `steer
` backup
`
`----------------------------------------------------------------
`----------------------------------------------------------------

loopDeloop:
if pinC.6 = 1 then
low enFR, enLR ` Shut Drive Motors
pause 20
goto loopDeloop
else
goto mainProg
endif



mainProg:

high ledGrn, ledBlu, ledRed `warning lights off

` ----- move forward, evaluate, proceed, unless backup
gosub lookFwd ` get Value in rtFrontSensor
gosub lookBak ` get Value in backUpSensor

if frontSensor >= frontLimit OR frontSensor >= irLimit then
low enFR,enLR `stop
low ledGrn
low enFR, enLR ` Shut Drive Motors
pause 20
gosub goBack
goto loopDeloop
endif


if lftFrontSensor >= lftLimit OR lftFrontSensor >= irLimit then ; reached the limit:stop:in this version
low enFR,enLR `stop
low ledRed
low enFR, enLR ` Shut Drive Motors
pause 20
gosub steerRight
; goto loopDeloop
endif

if rtFrontSensor >= rgtLimit OR rtFrontSensor >= irLimit then
low enFR,enLR `stop
low ledBlu
low enFR, enLR ` Shut Drive Motors
pause 20
gosub steerLeft
; goto loopDeloop
endif

if rearSensor >= backLimit then
low ledGrn, ledBlu, ledRed `warning lights white (backup something stuck behind bot)

low enFR,enLR `stop
goto loopDeloop
endif

; if rearSensor < backLimit then
; high enFR
; low fwdRev `go forward
; pause 50 `kick brakes off, etc
; endif

high enFR, fwdRev `go forward
low enLR ` I said Forward Fool!
pause 50 `kick brakes off, etc

goto mainProg
`

lookFwd:
` RIGHT
;----- Look rtFrontSensor
let sensorTemp = rtFrontSensor ` last sample
readadc10 frontRight, rtFrontSensor ` sonar ana input
pause 10 `steady... steady...
rtFrontSensor = rtFrontSensor + sensorTemp
rtFrontSensor = rtFrontSensor / 2

` LEFT
;----- Look lftFrontSensor
let sensorTemp = lftFrontSensor ` last sample
readadc10 frontLeft,lftFrontSensor
pause 10 `let it settle
lftFrontSensor = lftFrontSensor + sensorTemp
lftFrontSensor = lftFrontSensor / 2

;----- CENTER FRONT
let sensorTemp = frontSensor ` last sample
readadc10 frontCenter,frontSensor
pause 10 `let it settle
frontSensor = frontSensor + sensorTemp
frontSensor = frontSensor / 2
return

lookBak:
;----- Look back Sensor
let sensorTemp = rearSensor ` last sample
readadc10 backCenter, rearSensor ` sonar ana input
pause 10 `steady... steady...
rearSensor = rearSensor + sensorTemp
rearSensor = rearSensor / 2
return


goForth:
high enFR
high fwdRev `forward
pause 100
low fwdRev,enFR `stop
pause 60
return


goBack:
high enFR
low fwdRev `reverse
pause 3100
low fwdRev,enFR `stop
pause 600
return


steerLeft:
high enLR `left
low lftRgt
pause 1500
low enLR `stop
gosub goForth
pause 60
return


steerRight:
high enLR
high lftRgt `right
pause 1500
low enLR
gosub goForth
pause 60
return