I have obtained a pixAxe 18m2 to replace an 18x I was using in a project. The "m2" is the bees-knees for the things I am putting it through.

HOT STUFF and COLD STUFF

Hot list first, it`s the longest. It`s multi-tasking! I couldn`t believe it. No more timer problems (so far) driving pwm timers and servo timing. It seems much nicer now. You can run four tasks at a time and have complete programmatic task control.

And still you have interrupts! What a joy. Right now I`m playing around with a controller that`s sort of a half breed using pwm and electronic motor control to drive a two-wheeled bot.

Where the fun comes in now is fun with distance, since I can read on one of the many ADC`s from an IR rangefinder. Not only can I look for objects, I can react to them differently as I check things out in the area. Thanks for the multiprocessing.

And, to make that even better, you can bump the 4mHz / 8mHz timing up as high as 32 mHz, although you lose the correct timing for servos if you go above 16mHz :-) ROFL

Thus each of the 4 processes can rip along like they think they are running on 8mHz chips... Again, a winner!

Legs are replaced by port.pin dot annotation. So no pin/leg issues for my muddled old brain.

I haven`t tried `em yet, but there are capacitive touch inputs, fancy capacitive touch sensors like on an I-something. I will try them.

I have tried the all-new "reset button as input button". No reset button. I like it though, mine runs a process that starts up the motors during short test runs of my latest bot.

This is pretty nice:

Check out the listing. Notice how you can stop processing running and then restart them. Note the drive forward process, it is stopped when the motor stops when you get too close to an object. You can see the task management in the software:

#rem
```````````````````````````````````````````````````
` PicAxe 18M2
` Pinout and Definition of Legs
`
`(DAC / Touch / ADC / Out / In) C.2 leg 1
`(SRQ / Out) Serial Out / C.3 leg 2
`(In) / Serial In / C.4 leg 3
`(In) C.5 leg 4
`=======================================
`(gnd) 0v leg 5
`=======================================
`(SRI / Out / In) B.0 leg 6
`(i2c sda / Touch / ADC / Out / In) B.1 leg 7
`(hserin / Touch / ADC / Out / In) B.2 leg 8
`(pwm / Touch / ADC / Out / In) B.3 leg 9
`---------------------------------------
`(i2c scl / Touch / ADC / Out / In) B.4 leg 10
`(hserout / Touch / ADC / Out / In) B.5 leg 11
`(pwm / Touch / ADC / Out / In) B.6 leg 12
`(Touch / ADC / Out / In) B.7 leg 13
`=======================================
`(vcc) +v leg 14
`=======================================
`(Out / In) C.6 leg 15
`(Out / In) C.7 leg 16
`(Touch / ADC / Out / In) C.0 leg 17
`(Touch / ADC / Out / In) C.1 leg 18
`
` end 18M2 definition
`````````````````````````````````````````````````````
#endrem

` ------------------------------------------------------------
` Program Wide Symbols


`pins
symbol Piezo = B.2
symbol outPWM = B.3

`regVars
symbol ADCval = w0
symbol motorSpeed = w1
symbol TempA = w2
symbol TempB = w3
symbol warnDist = w4
symbol haltDist = w5

symbol true = 1 ` one or more
symbol false = 0 ` zero
`vars
symbol slowSpeed = 245 `carpet s250,m260,h300
symbol midSpeed = 250 `smooth s240,m280,h310
symbol hiSpeed = 300


` end Program Wide Symbols ----------------------------------

start0:
warnDist = 150 ` Somewhere between haltDist and around 80
haltDist = 410 ` 400 Least "sensitive" you are in 10 cm zone
`50 is most "sensitive", it`s pretty noisy and very picky
`80 is roughly 6ft away, nice burglar alarm for bedroom door
`400 is almost blind, things have to be 10cm zone to see `em
` set Motor Speed
gosub stopMotor
pwmout outPWM, 99, hiSpeed ` shake it baby hustle!

start1:
readadc10 C.1,ADCval ; read value into b1
pause 10 ; let value settle in
if ADCval > TempA then
TempA = ADCval `we are finding the maximum here
endif
` stop completely halt everything we are at limit (400ish)
if ADCval > haltDist then
TempA = 0
suspend 3
gosub stopMotor
gosub sirenHorn
gosub revMotor
pause 500
gosub stopMotor
pause 100
gosub turnL
pause 500
gosub stopMotor
` endif
` within sensor distance start gross evasive moves
elseif ADCval > warnDist then
gosub beepHorn
pwmduty outPWM,slowSpeed ` or turn right or left and back?
endif
pause 5 ; short delay
goto start1 ; loop back to start

start2:
if pinC.5 = 0 then
gosub beepHorn
pause 200
gosub beepHorn
pause 200
pause 1000
pwmduty outPWM,hiSpeed
resume 3
endif
pause 1000
goto start2

start3:
gosub fwdMotor
pause 20
goto start3


beepHorn:
sound Piezo,(122,40) ; make a sound,
return

sirenHorn:
sound Piezo,(120,30,125,30) ; make a siren
return

fwdMotor:
low B.0
high B.1
high B.4
low B.5
return

revMotor:
high B.0
low B.1
low B.4
high B.5
return


stopMotor:
low B.0
low B.1
low B.4
low B.5
`low outPWM
return

` Right and Left Steering Subroutines
`
turnR:
low b.0
high b.1
low b.4
high b.5
return

turnL:
high b.0
low b.1
high b.4
low b.5
return

The PWM signal and the Servo command both use the same timer, so does the sound command, so things got messy. I had to treat a lot more of it as if it was a serial process, in other words, like an 18x, not an 18m2.

That was my fault for making assumptions about the multitasking. I read and learned, so I took a different approach. It`s a bit of a blend between how I would do it on an 18x and how I would like it to work on an 18m2. But I am learning and expect to do a lot more later.

Here`s where the code stands now: I`m not doing the head movements, just allowing the head to sit still and provide distance measurements which I can use to judge how close to a thing the bot can get.

Listing:

`pins
symbol Piezo = C.2
symbol outPWM = B.3
symbol Xservo = B.6
symbol Yservo = B.7

`regVars
symbol ADCval = w0
symbol motorSpeed = w1
symbol TempA = w2
symbol TempB = w3
symbol TempC = w4
symbol haltDist = w5
symbol warnDist = w6

symbol true = 1 ` one or more
symbol false = 0 ` zero
`vars
symbol slowSpeed = 280 `carpet s250,m260,h300
symbol midSpeed = 310 `smooth s240,m280,h310
symbol hiSpeed = 360
symbol headUP = 116
symbol headDN = 90
symbol xHdCtr = 135
symbol yHdCtr = 110


` end Program Wide Symbols ----------------------------------

start0:
warnDist = 300 ` Somewhere between haltDist and around 80
haltDist = 410 ` 400 Least "sensitive" you are in 10 cm zone

gosub stopMotor
servo Xservo, xHdCtr
servo Yservo, yHdCtr
low Xservo
low Yservo
`gosub beepHorn
pause 1000
pwmout outPWM, 99, hiSpeed ` shake it baby hustle!

loopydupe1:
readadc10 C.1,ADCval ; read value into c1
pause 10 ; let value settle in
` stop completely halt everything we are at limit (400ish)
`sertxd("The value of adc is ",#w0,13,10)
`pause 200
if ADCval > haltDist then
TempA = 0
suspend 2
gosub stopMotor
gosub sirenHorn
pwmduty outPWM, hiSpeed
gosub revMotor
pause 300
gosub stopMotor
pause 100
gosub turnL
pause 200
gosub stopMotor
pwmduty outPWM, slowSpeed
pause 1000
resume 2
` within sensor distance start gross evasive moves
elseif ADCval > warnDist then
pwmduty outPWM, slowSpeed ` or turn right or left and back?
`gosub snoop
endif
pause 5 ; short delay
goto loopydupe1 ; loop back to start

start1:
if pinC.5 = 0 then
pause 1000
pwmduty outPWM, hiSpeed
resume 2
endif
pause 1000
goto start1

start2:
gosub fwdMotor
pause 20
goto start2



`Direction sensing
snoop:
`gosub stopMotor
gosub ctrHead
gosub upHead
for TempC = 50 to 200 step 10
servopos Xservo, TempC
pause 100
readadc10 C.1,ADCval ` read IR value
if ADCval > TempA then
TempA = ADCval `we are finding the maximum here
TempB = TempC `count
endif
next TempC

gosub dnHead
for TempC = 200 to 50 step -10
servopos Xservo, TempC
pause 100
readadc10 C.1,ADCval ` read IR value
if ADCval > TempA then
TempA = ADCval `we are finding the maximum here
TempB = TempC `count
endif
`stor largest and head position
next TempC

gosub ctrHead
pause 1000
`low Xservo
`low Yservo

return

beepHorn:
sound Piezo,(122,40) ; make a sound,
low Piezo ; sound off
return

sirenHorn:
`sound Piezo,(120,30,125,30) ; make a siren
pause 100
low Piezo
return

fwdMotor:
low B.0
high B.1
high B.4
low B.5
return

revMotor:
high B.0
low B.1
low B.4
high B.5
return


stopMotor:
low B.0
low B.1
low B.4
low B.5
`low outPWM
return

` Right and Left Steering Subroutines
`
turnR:
low b.0
high b.1
low b.4
high b.5
return

turnL:
high b.0
low b.1
high b.4
low b.5
return

`
ctrHead:
servopos Xservo, xHdCtr
pause 500
servo Yservo, yHdCtr ` set HeadPosition Indicator Flag CTR
pause 500
return

upHead:
servopos Yservo, headUP
` set HeadPosition Indicator Flag UP
return

dnHead:
servopos Yservo, headDN
` set HeadPosition Indicator Flag DN
return