You can build your own autonomous Robot by following the guidelines here. I like to think of them as guidelines, because it is your creative programming that will make this project most interesting.

I can get you started.

Put it together. There is a project with build it video on this site.

Then build the picAxe board. I built mine on perfboard, I simply ran wires to the proper places on the L 298 board. I used on board pins to setup the two Servos.

Here we have it "sewn together" for testing with everything punched into a balsa wood board.

I used the balsa wood so I could drill it easily and cut holes in it as well. This allowed me to experiment with a third wheel and other ideas with the platform, before replacing the balsa wood with a smaller hardwood piece.

#rem
```````````````````````````````````````````````````
` PicAxe 18M2
` Pinout and Definition of Legs
`
`(DAC / Touch / ADC / Out / In) C.2 leg 1
`(SRQ / Out) Serial Out / C.3 leg 2
`(In) / Serial In / C.4 leg 3
`(In) old reset is now signal C.5 leg 4
`=======================================
`(gnd) 0v leg 5
`=======================================
`(SRI / Out / In) B.0 leg 6
`(i2c sda / Touch / ADC / Out / In) B.1 leg 7
`(hserin / Touch / ADC / Out / In) B.2 leg 8
`(pwm / Touch / ADC / Out / In) B.3 leg 9
`---------------------------------------
`(i2c scl / Touch / ADC / Out / In) B.4 leg 10
`(hserout / Touch / ADC / Out / In) B.5 leg 11
`(pwm / Touch / ADC / Out / In) B.6 leg 12
`(Touch / ADC / Out / In) B.7 leg 13
`=======================================
`(vcc) +v leg 14
`=======================================
`(Out / In) C.6 leg 15
`(Out / In) C.7 leg 16
`(Touch / ADC / Out / In) C.0 leg 17
`(Touch / ADC / Out / In) C.1 leg 18
`
` end 18M2 definition
`````````````````````````````````````````````````````
#endrem

` ------------------------------------------------------------
` Program Wide Symbols

`#terminal 4800
`pins
symbol Piezo = C.2
symbol outPWM = B.3
symbol Xservo = B.6
symbol Yservo = B.7

`regVars
symbol ADCval = w0
symbol motorSpeed = w1
symbol haltDist = w2
symbol warnDist = w3
symbol hiMaxVal = w4
symbol hiCount = w5
symbol loMaxVal = w6
symbol loCount = w7
symbol tempCount = w8
symbol pointToX = w9
symbol pointToY = w10
symbol westSide = w11
symbol eastSide = w12
symbol northSide = w13

symbol true = 1 ` one or more
symbol false = 0 ` zero
`vars
symbol slowSpeed = 250 `carpet s250,m260,h300
symbol midSpeed = 280 `smooth s240,m280,h310
symbol hiSpeed = 320
symbol headUP = 126
symbol headDN = 80
symbol xHdCtr = 135
symbol yHdCtr = 90
symbol headEast = 60 `east = 40
symbol headWest = 210`west = 230
symbol nEast = 75 `xHdCtr - headEast /2
symbol nWest = 180 `xHdCtr - headWest /2

` end Program Wide Symbols ---------------------



` ------------ PROGRAM SPACE ------------------
` Program wide vars and symbols
warnDist = 60 ` Somewhere between haltDist and around 80
haltDist = 200 ` 400 Least "sensitive" you are in 10 cm zone
`50 is most "sensitive", it`s pretty noisy and very picky
`80 is roughly 6ft away, nice burglar alarm for bedroom door
`400 is almost blind, things have to be 10cm zone to see `em
` set Motor Speed

gosub beepHorn
pause 100
gosub lookAround
pause 300
pwmout outPWM, 99, hiSpeed ` select motor speed

start0:
`sertxd("ptr:values ",13,10)
gosub ctrHead
gosub fwdMotor
goto start0


object_track:
readadc10 C.1, ADCval ; read value into c1
pause 100 ; let value settle in
`resume 2
`sertxd( #ADCval," : ", #ADCval,13,10)
return

lookAround:
pointToX = headWest
gosub moveHeadX
gosub object_track
westSide = ADCval

pointToX = headEast
gosub moveHeadX
gosub object_track
eastSide = ADCval

pointToX = xHdCtr ` just to help keep track
pointToY = yHdCtr ` ctrHead can do without
gosub ctrHead
gosub object_track
northSide = ADCval
return
`
moveHeadX:
`pointToX (w9) should have n,ne,nw,e,w
for tempCount = 1 To 40
pulsout Xservo,pointToX ; send a pointToX ms pulse out of pin 1
pause 10 ; pause 10 ms
next tempCount

return

moveHeadY:
`pointToY preset with where to point head
for tempCount = 1 To 40
pulsout Yservo, pointToY ; send a pointToY ms pulse out of pin 1
pause 10 ; pause 10 ms
next tempCount



ctrHead:

for tempCount = 1 To 20
pulsout Xservo,xHdCtr ; send a 1.50ms pulse out of pin 1
pause 10 ; pause 10 ms
next tempCount

for tempCount = 1 To 20
pulsout Yservo,yHdCtr ; send a 1.50ms pulse out of pin 1
pause 10 ; pause 10 ms
next tempCount

return



`--- Driving Routines
`
fwdMotor:
gosub object_track
if ADCval > warnDist then
pwmout outPWM, 99, slowSpeed ` select motor speed
endif
if ADCval > haltDist then
gosub stopMotor
pwmout outPWM, 99, midSpeed ` backing out motor speed
pause 100
gosub revMotor `back up
pause 750 ` for 550 count (certainly changeable)
gosub stopMotor
` make directional change decisions
gosub lookAround
pause 100
` westSide eastSide northSide values tested here
if eastSide > westSide AND eastSide > northSide then
gosub turnL
pause 300
endif
if westSide > eastSide AND westSide > northSide then
gosub turnR
pause 300
endif
gosub stopMotor
`gosub lookAround
if northSide > westSide AND northSide > eastSide then
gosub revMotor
pause 300
gosub turnR
pause 500 `very far
gosub stopMotor
endif
pwmout outPWM, 99, midSpeed ` be cautions motor speed
endif
gosub ctrHead
low B.0
high B.1
high B.4
low B.5
return

revMotor:
high B.0
low B.1
low B.4
high B.5
return


stopMotor:
low B.0
low B.1
low B.4
low B.5
`low outPWM
return


` Right and Left Steering Subroutines
`
turnR:
low b.0
high b.1
low b.4
high b.5
return

turnL:
high b.0
low b.1
high b.4
low b.5
return


`-- Horn Feedback Routines
`
beepHorn:
tune Piezo, 4, %00000000,($00,$41,$00)
low Piezo ; sound off
return

sirenHorn:
tune Piezo, 4, %00000000,($00,$01,$40,$00)
low Piezo
return